By printing a text file through the printer port, you can send an AppleWorks word processor file to the Macintosh. You can make the text file by selecting the disk drive as the "Printer" in the "Specify Printer Information" section.
You may have some problems with the communications program you are using on the Macintosh. For instance, MacTerminal will ignore all characters past the 80th character if it does not receive a carriage return (in fact, this was the reason for the change in AppleWorks 2.0). Microsoft Works requires that you enter a "Capture Text" mode; otherwise, it will receive just one page of information.
AppleWorks 1.3 or earlier will print the file to a text file with carriage returns at the end of every paragraph. After it is in a text file, you can use a terminal program, such as Access II, to send the file over the modem line. If you do not have a communications program, then the following small BASIC program should suffice:
5 ONERR GOTO 90
7 SLOT = 1
10 D$ = CHR$(4)
15 F$ = "textfile" : REM You may use any file name.
17 PRINT D$;"PR#";SLOT
20 PRINT D$;"OPEN";F$
30 PRINT D$;"READ";F$
40 GET A$
60 PRINT A$;
80 GOTO 40
90 PRINT D$;"CLOSE"
95 PRINT D$;"PR#0"
100 END
AppleWorks 2.0 inserts a carriage return at the end of every line when printing to disk. However, the program below strips off the carriage returns if the following character is not a space or another carriage return.
10 ONERR GOTO 130
20 O$ = "oldfilename" : REM You may use any file name.
30 N$ = "newfilename" : REM You may use any file name.
40 D$ = CHR$(4)
50 PRINT D$;"OPEN";O$
60 PRINT D$;"OPEN";N$
70 PRINT D$;"READ";O$
80 GET A$
82 IF A$ <> CHR$(13) THEN 100
83 B$ = A$
84 GET A$
86 IF A$ <> CHR$(13) AND A$ <> " " THEN B$ = " " : REM Convert CR to space
88 PRINT D$;"WRITE";N$
90 PRINT B$; : GOTO 110
100 PRINT D$;"WRITE";N$
110 PRINT A$;
120 GOTO 70
130 PRINT D$;"CLOSE"
140 END
After you have passed the text file through this "pre-processor", you can transmit it with the first program.